Forums | MacLife

(* Not in Any Playlist iPod v1.0

"Not In Any Playlist" written by Doug Adams
iPod version hacked by Kosh

Get more free AppleScripts for iTunes and
help writing your own:
http://www.malcolmadams.com/itunes/
*)
global newContents

tell application "iTunes"
    
    set file_name to (choose file name with prompt "Enter a name for the text file:" default name "")
    if file_name is false then error number -128 -- cancel
    if file_name as string does not end with ".txt" then set file_name to ((file_name as string) & ".txt")
    
    display dialog "Gathering information..." buttons {""} giving up after 2
    
    set lib to a reference to (playlist 1 of (item 1 in (sources whose kind is iPod)))
    --    set lib to a reference to library playlist 1
    set c to count of every track of lib
    set everyP to (get a reference to every user playlist of (item 1 in (sources whose kind is iPod)))
    set allIDs to {}
    
    with timeout of 300000 seconds
        repeat with thisP in everyP
            if (class of thisP) is user playlist then
                if smart of thisP is true then
                    -- fugedabowdit
                else
                    repeat with tt from 1 to (count of every track of thisP)
                        copy (get database ID of track tt of thisP) to anid
                        if anid is not in allIDs then copy anid to end of allIDs
                    end repeat
                end if
            end if
        end repeat
    end timeout
    
    display dialog "Checking tracks..." buttons {""} giving up after 2
    set newContents to {}
    repeat with tt from 1 to count of every track of lib
        with timeout of 300000 seconds
            set aTr to (a reference to track tt of lib)
            tell aTr
                if allIDs does not contain database ID then
                    set nom to name
                    set alb to album
                    set art to artist
                    tell me to add_this_to_newContents(("- " & nom & " [artist: " & art & ", album: " & alb & "]" & return) as string)
                    -- beep
                end if
            end tell
        end timeout
    end repeat
end tell

set newContents to ("Not In Any Playlist - " & ((current date) as string) & return & return & (newContents as string))

try
    copy (a reference to (open for access file_name with write permission)) to fileRef
    write newContents to fileRef
    close access fileRef
on error errx number errNum
    close access fileRef
    display dialog "There has been an error creating the file:" & return & return & errx & return & "error number: " & errNum buttons {"Cancel"}
end try

set dMes2 to return & return & "Would you like to open the text file with TextEdit?"
set myEnding to (display dialog "Done!" & dMes2 buttons {"No, Just Quit", "Yes"} default button 2 with icon 1 giving up after 30)
if button returned of myEnding is "Yes" or gave up of myEnding is true then
    tell application "TextEdit"
        activate
        try
            open (file_name as alias)
        on error errMs
            display dialog errMs buttons {"Cancel"}
        end try
    end tell
end if
-------
to add_this_to_newContents(x)
    copy x as string to end of newContents
end add_this_to_newContents